Use directional albedo for prefiltered environment lighting (#2808)

While working on other changes, I noticed that the GLSL prefiltered environment lighting code path was only performing a single evaluation of the `F` and `G` terms, leading to innaccurate results for rougher materials. To get an approximation of the correct behaviour, we need to account for the particular Fresnel function in use. To that end, I've introduced a new variation of `mx_ggx_dir_albedo()`.

Author: shill-lucasfilm

libraries/pbrlib/genglsl/lib/mx_environment_prefilter.glsl

@@ -15,9 +15,8 @@ vec3 mx_environment_radiance(vec3 N, vec3 V, vec3 X, vec2 alpha, int distributio
     float NdotV = clamp(dot(N, V), M_FLOAT_EPS, 1.0);
 
     float avgAlpha = mx_average_alpha(alpha);
-    vec3 F = mx_compute_fresnel(NdotV, fd);
-    float G = mx_ggx_smith_G2(NdotV, NdotV, avgAlpha);
-    vec3 FG = fd.refraction ? vec3(1.0) - (F * G) : F * G;
+    vec3 FG = mx_ggx_dir_albedo(NdotV, avgAlpha, fd);
+    FG = fd.refraction ? vec3(1.0) - FG : FG;
 
     vec3 Li = mx_latlong_map_lookup(L, $envMatrix, mx_latlong_alpha_to_lod(avgAlpha), $envRadiance);
     return Li * FG * $envLightIntensity;

libraries/pbrlib/genglsl/lib/mx_microfacet_specular.glsl

@@ -476,12 +476,41 @@ vec3 mx_compute_fresnel(float cosTheta, FresnelData fd)
     {
         return mx_fresnel_conductor(cosTheta, fd.ior, fd.extinction);
     }
-    else
+    else // FRESNEL_MODEL_SCHLICK
     {
         return mx_fresnel_hoffman_schlick(cosTheta, fd);
     }
 }
 
+// Directional albedo accounting for different Fresnel functions.
+vec3 mx_ggx_dir_albedo(float NdotV, float alpha, FresnelData fd)
+{
+    if (fd.airy)
+    {
+        // Approximation using a blend between mirror (alpha = 0)
+        // and rougher cases. This helps to maintain angular
+        // color variation at lower roughness values.
+        vec3 mirrorDirAlbedo = mx_compute_fresnel(NdotV, fd);
+        vec3 F0 = mx_fresnel_airy(1.0, fd);
+        vec3 roughDirAlbedo = mx_ggx_dir_albedo(NdotV, alpha, F0, vec3(1.0));
+        return mix(mirrorDirAlbedo, roughDirAlbedo, sqrt(alpha));
+    }
+    else if (fd.model == FRESNEL_MODEL_DIELECTRIC)
+    {
+        float F0 = mx_ior_to_f0(fd.ior.x);
+        return mx_ggx_dir_albedo(NdotV, alpha, vec3(F0), vec3(1.0));
+    }
+    else if (fd.model == FRESNEL_MODEL_CONDUCTOR)
+    {
+        vec3 F0 = mx_fresnel_conductor(1.0, fd.ior, fd.extinction);
+        return mx_ggx_dir_albedo(NdotV, alpha, F0, vec3(1.0));
+    }
+    else // FRESNEL_MODEL_SCHLICK
+    {
+        return mx_ggx_dir_albedo(NdotV, alpha, fd.F0, fd.F90);
+    }
+}
+
 // Compute the refraction of a ray through a solid sphere.
 vec3 mx_refraction_solid_sphere(vec3 R, vec3 N, float ior)
 {