dgop/flake.nix at master · AvengeMedia/dgop · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
{
  description = "API & CLI for System Resources";

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";
  };

  outputs =
    { self, nixpkgs }:
    let
      supportedSystems = [
        "x86_64-linux"
        "aarch64-linux"
        "x86_64-darwin"
        "aarch64-darwin"
      ];

      forAllSystems =
        f:
        builtins.listToAttrs (
          map (system: {
            name = system;
            value = f system;
          }) supportedSystems
        );

    in
    {
      packages = forAllSystems (
        system:
        let
          pkgs = import nixpkgs { inherit system; };
          inherit (pkgs) lib;
        in
        {
          dgop = pkgs.buildGoModule (finalAttrs: {
            pname = "dgop";
            version = "0.1.11";
            src = ./.;
            vendorHash = "sha256-3mnYgWrS8J4zyYEin+cVfYHwYAMZDAMZBk34V8KLUMc=";

            ldflags = [
              "-s"
              "-w"
              "-X main.Version=${finalAttrs.version}"
              "-X main.buildTime=1970-01-01_00:00:00"
              "-X main.Commit=${finalAttrs.version}"
            ];

            nativeBuildInputs = with pkgs; [
              installShellFiles
              makeWrapper
            ];

            installPhase = ''
              mkdir -p $out/bin
              cp $GOPATH/bin/dgop $out/bin/dgop
              wrapProgram $out/bin/dgop --prefix PATH : "${lib.makeBinPath [ pkgs.pciutils ]}"

              installShellCompletion --cmd dgop \
                  --bash <($out/bin/dgop completion bash) \
                  --fish <($out/bin/dgop completion fish) \
                  --zsh <($out/bin/dgop completion zsh)
            '';

            meta = {
              description = "API & CLI for System Resources";
              homepage = "https://github.com/AvengeMedia/dgop";
              mainProgram = "dgop";
              binaryNativeCode = true;
              license = lib.licenses.mit;
              platforms = lib.platforms.unix;
              maintainers = with lib.maintainers; [ lonerOrz ];
            };
          });

          default = self.packages.${system}.dgop;
        }
      );
    };
}