gsim/flake.nix at master · OpenXiangShan/gsim · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
{
  description = "GSIM: A Fast RTL Simulator for Large-Scale Designs";

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-25.11";
  };

  outputs = { self, nixpkgs, ... }:
    let
      systems = nixpkgs.lib.systems.flakeExposed;
      perSystem = nixpkgs.lib.genAttrs systems (system:
        let
          pkgs = import nixpkgs { inherit system; };
          llvm = pkgs.llvmPackages_19;
          gsim = llvm.stdenv.mkDerivation {
            pname = "gsim";
            version = "1.0.0-dev"; # FIXME?
            src = self;

            strictDeps = true;
            enableParallelBuilding = true;
            dontConfigure = true;

            nativeBuildInputs = [
              pkgs.flex
              pkgs.bison
            ];
            buildInputs = [
              pkgs.flex
              pkgs.gmp
            ];

            makeFlags = [
              # gsim defaults to /bin/bash, which is not guaranteed in NixOS
              "SHELL=${llvm.stdenv.shell}"
              # override default build target to avoid running tests
              "build-gsim"
            ];

            installPhase = ''
              runHook preInstall
              install -Dm755 build/gsim/gsim $out/bin/gsim
              runHook postInstall
            '';

            meta = {
              description = "Fast RTL Simulator for Large-Scale Designs";
              homepage = "https://github.com/OpenXiangShan/gsim";
              platforms = pkgs.lib.platforms.linux;
            };
          };
        in
        {
          packages = {
            gsim = gsim;
            default = gsim;
          };
        }
      );
    in
    {
      packages = nixpkgs.lib.mapAttrs (_: v: v.packages) perSystem;
    };
}