emoji-board/flake.nix at master · Quoteme/emoji-board · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
{
  description = "Emoji Keyboard for Wayland";

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";
    flake-utils.url = "github:numtide/flake-utils";
  };

  outputs = { self, nixpkgs, flake-utils }:
    flake-utils.lib.eachDefaultSystem (system:
      let
        pkgs = nixpkgs.legacyPackages.${system};
        myGHC = pkgs.haskellPackages.ghcWithPackages (ps: with ps; [
          aeson
          base
          text
          string-interpolate
          hs-openmoji-data
          fuzzily
          gi-gtk
        ]);
      in
      rec
      {
        defaultPackage = packages.emoji-keyboard;
        packages.emoji-keyboard = pkgs.stdenv.mkDerivation (finalAttrs: {
          pname = "emoji-keyboard";
          version = "1.0";

          src = ./src;

          nativeBuildInputs = with pkgs; [
            makeWrapper
          ];

          buildInputs = with pkgs; [
            kdotool
            ydotool
            wl-clipboard
            myGHC
          ];

          buildPhase = ''
            mkdir build
            cd build
            cp -r $src/* .
            ghc Main.hs
            mv Main emoji-keyboard
          '';

          installPhase = ''
            mkdir -p $out/bin
            cp emoji-keyboard $out/bin/
            # copy over the .desktop file
            mkdir -p $out/share/applications
            cp assets/emoji-keyboard.desktop $out/share/applications/
            chmod +x $out/bin/emoji-keyboard
          '';

          preFixup = ''
            wrapProgram "$out/bin/emoji-keyboard" \
              --prefix PATH : ${pkgs.kdotool}/bin \
              --prefix PATH : ${pkgs.ydotool}/bin \
              --prefix PATH : ${pkgs.wl-clipboard}/bin
          '';

          meta = {
            description = "An emoji-keyboard";
            homepage = "";
          };
        });

        devShell = pkgs.mkShell {
          buildInputs = with pkgs; [
            kdotool
            ydotool
            wl-clipboard
            myGHC
            haskell-language-server
            haskellPackages.haskell-dap
            haskellPackages.ghci-dap
            haskellPackages.haskell-debug-adapter
          ];

          shellHook = ''
            echo "Welcome to the emoji-keyboard dev shell"
          '';
        };
      }
    );
}