Kotson/build.gradle at master · SalomonBrys/Kotson · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
buildscript {
    ext.kotlin_version = '1.1.51'

    repositories {
        mavenCentral()
    }
    dependencies {
        classpath "org.jetbrains.kotlin:kotlin-gradle-plugin:$kotlin_version"
    }
}

apply plugin: 'kotlin'

apply plugin: 'maven'
apply plugin: 'signing'

group = "com.github.salomonbrys.kotson"
version = '2.5.0'

task javadocJar(type: Jar) {
    classifier = 'javadoc'
    from javadoc
}

task sourcesJar(type: Jar) {
    classifier = 'sources'
    from sourceSets.main.allSource
}

artifacts {
    archives javadocJar, sourcesJar
}

signing {
    required { gradle.taskGraph.hasTask(tasks.uploadArchives) }
    sign configurations.archives
}

sourceSets {
    main.java.srcDirs += 'src/main/kotlin'
}

repositories {
    mavenCentral()

    maven {
        url 'http://repository.jetbrains.com/repo'

    }
}

dependencies {
    compile "com.google.code.gson:gson:2.8.0"

    compile "org.jetbrains.kotlin:kotlin-stdlib:$kotlin_version"

    testCompile "org.jetbrains.kotlin:kotlin-reflect:$kotlin_version"
    testCompile "org.jetbrains.kotlin:kotlin-test:$kotlin_version"
    testCompile 'org.jetbrains.spek:spek-api:1.1.5'
}

test {
    testLogging {
        showExceptions = true
        showStackTraces = true
        exceptionFormat = "full"
        events = ["failed", "skipped"]
        showStandardStreams = true
    }
}

if (hasProperty('ossrhUsername') && hasProperty('ossrhPassword')) {
    uploadArchives {
        repositories {
            mavenDeployer {
                beforeDeployment { MavenDeployment deployment -> signing.signPom(deployment) }

                repository(url: "https://oss.sonatype.org/service/local/staging/deploy/maven2/") {
                    authentication(userName: ossrhUsername, password: ossrhPassword)
                }

                snapshotRepository(url: "https://oss.sonatype.org/content/repositories/snapshots/") {
                    authentication(userName: ossrhUsername, password: ossrhPassword)
                }

                pom.project {
                    name 'Kotson'
                    packaging 'jar'
                    artifactId 'kotson'
                    description 'Kotlin bindings for JSON manipulation via Gson'
                    url 'https://github.com/SalomonBrys/Kotson'

                    licenses {
                        license {
                            name 'MIT'
                            url 'http://opensource.org/licenses/MIT'
                        }
                    }

                    developers {
                        developer {
                            id 'salomonbrys'
                            name 'Salomon BRYS'
                            email 'salomon.brys@gmail.com'
                        }
                    }

                    scm {
                        url 'https://github.com/SalomonBrys/Kotson'
                        connection 'scm:git:https://github.com/SalomonBrys/Kotson.git'
                        developerConnection 'scm:git:git@github.com:SalomonBrys/Kotson.git'
                        tag 'HEAD'
                    }

                    issueManagement {
                        system 'GitHub Issues'
                        url 'https://github.com/SalomonBrys/Kotson/issues'
                    }
                }
            }
        }
    }
}