tds/settings.gradle.kts at main · Unidata/tds · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
/*
 * Copyright (c) 2026 University Corporation for Atmospheric Research/Unidata
 * See LICENSE for license information.
 */

dependencyResolutionManagement {
  repositoriesMode = RepositoriesMode.FAIL_ON_PROJECT_REPOS
  repositories {
    // be very specific about where non-maven-central-based artifacts are sourced
    exclusiveContent {
      forRepository {
        maven {
          name = "unidata-3rdparty"
          url = uri("https://artifacts.unidata.ucar.edu/repository/unidata-3rdparty/")
        }
      }
      filter { includeModule("org.bounce", "bounce") }
    }

    // use unidata-all so that excluseiveContent can be used
    // (as of 9.3.0, cannot have overlapping filters even when repositories are
    // configured for release or snapshot only)
    exclusiveContent {
      forRepository {
        maven {
          name = "unidata-all"
          url = uri("https://artifacts.unidata.ucar.edu/repository/unidata-all/")
        }
      }
      filter {
        // direct
        includeModule("EDS", "nciso-common")
        includeModule("edu.ucar", "bufr")
        includeModule("edu.ucar", "cdm-core")
        includeModule("edu.ucar", "cdm-image")
        includeModule("edu.ucar", "cdm-mcidas")
        includeModule("edu.ucar", "cdm-misc")
        includeModule("edu.ucar", "cdm-radial")
        includeModule("edu.ucar", "cdm-s3")
        includeModule("edu.ucar", "cdm-zarr")
        includeModule("edu.ucar", "cdm-test-utils")
        includeModule("edu.ucar", "dap4")
        includeModule("edu.ucar", "gcdm")
        includeModule("edu.ucar", "grib")
        includeModule("edu.ucar", "httpservices")
        includeModule("edu.ucar", "netcdf4")
        includeModule("edu.ucar", "netcdf-java-bom")
        includeModule("edu.ucar", "opendap")
        includeModule("edu.ucar", "uicdm")
        includeModule("edu.ucar", "waterml")
        includeModule("edu.ucar.unidata", "libblosc2-native")

        includeModule("uk.ac.rdg.resc", "edal-cdm")
        includeModule("uk.ac.rdg.resc", "edal-common")
        includeModule("uk.ac.rdg.resc", "edal-graphics")
        includeModule("uk.ac.rdg.resc", "edal-godiva")
        includeModule("uk.ac.rdg.resc", "edal-wms")

        // transitive
        includeModule("EDS", "threddsIso-parent")
        includeModule("edu.ucar", "jj2000")
        includeModule("edu.ucar", "libaec-jna")
        includeModule("edu.ucar", "libblosc2-jna")
        includeModule("edu.ucar", "netcdf-java-platform")
        includeModule("edu.ucar", "udunits")
        includeModule("edu.ucar", "uibase")
        includeModule("edu.ucar.unidata", "libaec-native")
        includeModule("edu.ucar.unidata", "libblosc2-native")
        includeModule("edu.wisc.ssec", "visad-mcidas-slim-ucar-ns")
        includeModule("uk.ac.rdg.resc", "edal")
        includeModule("uk.ac.rdg.resc", "edal-coveragejson")

        // transitive from nciso...problematic
        includeModule("edu.ucar", "netcdf-java-testing-platform")
        includeModule("edu.ucar", "tds-plugin-bom")
        includeModule("edu.ucar", "tds-platform")
      }
    }
    mavenCentral()
  }
  versionCatalogs { create("tdsLibs") { from(files("gradle/tds.libs.versions.toml")) } }
}

includeBuild("build-logic-tds")

rootProject.name = "thredds-data-server"

//
// no subproject dependencies
//
include(":d4servlet")

project(":d4servlet").projectDir = file("dap4/d4servlet")

include(":docs")

include(":tdcommon")

include(":tds-ugrid")

include(":tds-gcdm")

// depends on :d4servlet
include(":d4ts")

project(":d4ts").projectDir = file("dap4/d4ts")

// depends on tdcommon
include(":tds-test-utils")

include(":tdm")

// depends on tds-test-utils
include(":opendap-servlet")

project(":opendap-servlet").projectDir = file("opendap/server")

// depends on opendap-servlet
include(":dtswar")

project(":dtswar").projectDir = file("opendap/dtswar")

// depends on tds-ugrid

include(":tds-ui")

// the TDS

include(":tds")

//
// platforms used by all
//
include("tds-platform")

include("tds-testing-platform")

include(
  "tds-plugin-bom"
)

// To debug netCDF-Java, uncomment the two includeBuild calls
// below to create a composite build, making sure to point them
// to your local copy of the netCDF-Java repository

// includeBuild("../netcdf-java/build-logic-ncj")

// includeBuild("../netcdf-java")