generate-action.pkl

//===----------------------------------------------------------------------===//
// Copyright © 2025 Apple Inc. and the Pkl project authors. All rights reserved.
//
// Licensed under the Apache License, Version 2.0 (the "License");
// you may not use this file except in compliance with the License.
// You may obtain a copy of the License at
//
//     https://www.apache.org/licenses/LICENSE-2.0
//
// Unless required by applicable law or agreed to in writing, software
// distributed under the License is distributed on an "AS IS" BASIS,
// WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
// See the License for the specific language governing permissions and
// limitations under the License.
//===----------------------------------------------------------------------===//
/// Generates a typed step that calls out to a GitHub Action.
///
/// The types for an action can be enhanced with types from typesafegithub.
/// It will look either at the repo's `action-types.yml` file, or within
/// [github-actions-typing-catalog](https://github.com/typesafegithub/github-actions-typing-catalog)
/// to determine the corresponding types.
///
/// If actions are missing in either of these sources, use the programmatic [ActionGenerator] instead.
///
/// Sample usage:
///
///     pkl eval package://pkg.pkl-lang.org/pkl-pantry/com.github.actions.contrib@<VERSION>#/generate-action.pkl \
///       -m . \
///       -p action-name=actions/checkout@v4
///
/// Optionally, you can specify a different GitHub Actions package with the `action-package-name` parameter
@ModuleInfo { minPklVersion = "0.30.0" }
module com.github.actions.contrib.`generate-action`

import "ActionGenerator.pkl"

/// The name of the action that should be generated.
///
/// Should include the version string.
actionName: ActionGenerator.ActionName = read("prop:action-name")

/// Optional override of the GitHub actions package.
githubActionsPackageName: String? = read?("prop:action-package-name")

local generator: ActionGenerator = new {
  actionName = module.actionName
  when (module.githubActionsPackageName != null) {
    githubActionsPackageName = module.githubActionsPackageName
  }
}

fixed files: Mapping<String, FileOutput> = new {
  // noinspection TypeMismatch
  ["\(generator.modulePath.join("/"))/\(generator.moduleName).pkl"] {
    text = generator.result
  }
}

output {
  text = throw("I must be called using the `-m` flag.")
  files = module.files
}