feat(stdlib): Add lastIndexOf function to String module (#1372)

Author: spotandjake

compiler/test/stdlib/string.test.gr

@@ -69,6 +69,17 @@ assert String.indexOf("🚀", emojis) == Some(15)
 assert String.indexOf(short, short) == Some(0)
 assert String.indexOf(emoji, emojis) == None
 assert String.indexOf("aa", "aaa") == Some(0)
+assert String.indexOf("world", "Hello world world") == Some(6)
+// lastIndexOf tests
+assert String.lastIndexOf(empty, empty) == Some(0)
+assert String.lastIndexOf(empty, short) == Some(3)
+assert String.lastIndexOf(short, fox) == Some(16)
+assert String.lastIndexOf("🚀", emojis) == Some(15)
+assert String.lastIndexOf("🌾", "🌾🌾🌾🌾🌾") == Some(4)
+assert String.lastIndexOf(short, short) == Some(0)
+assert String.lastIndexOf(emoji, emojis) == None
+assert String.lastIndexOf("aa", "aaa") == Some(1)
+assert String.lastIndexOf("world", "Hello world world") == Some(12)
 
 // charAt tests
 assert String.charAt(0, emojis) == 'w'

stdlib/string.gr

@@ -11,6 +11,7 @@ import Memory from "runtime/unsafe/memory"
 import Exception from "runtime/exception"
 import Conv from "runtime/unsafe/conv"
 import {
+  untagSimpleNumber,
   tagSimpleNumber,
   tagChar,
   untagChar,
@@ -100,7 +101,7 @@ export let byteLength = (string: String) => {
 }
 
 /**
- * Finds the position of a substring in the input string.
+ * Finds the first position of a substring in the input string.
  *
  * @param search: The substring to find
  * @param string: The string to inspect
@@ -161,6 +162,65 @@ export let indexOf = (search: String, string: String) => {
   }
 }
 
+/**
+ * Finds the last position of a substring in the input string.
+ *
+ * @param search: The substring to find
+ * @param string: The string to inspect
+ * @returns `Some(position)` containing the starting position of the substring if found or `None` otherwise
+ *
+ * @example String.lastIndexOf("world", "Hello world world") == Some(12)
+ *
+ * @since v0.5.3
+ */
+@unsafe
+export let lastIndexOf = (search: String, string: String) => {
+  // The last possible index in the string given the length of the search
+  let lastIndex = length(string) - length(search)
+
+  let (>) = WasmI32.gtU
+  let (>=) = WasmI32.geU
+  let (==) = WasmI32.eq
+  let (!=) = WasmI32.ne
+  let (+) = WasmI32.add
+  let (-) = WasmI32.sub
+  let (&) = WasmI32.and
+
+  let search = WasmI32.fromGrain(search)
+  let string = WasmI32.fromGrain(string)
+  let searchSize = WasmI32.load(search, 4n)
+  let stringSize = WasmI32.load(string, 4n)
+  if (searchSize > stringSize) {
+    None
+  } else {
+    let mut matchIndex = -1n
+    let mut stringIndex = untagSimpleNumber(lastIndex)
+    let searchPtr = search + 8n
+    let stringStartPtr = string + 8n
+    for (
+      let mut stringPtr = stringStartPtr + stringSize - searchSize;
+      stringPtr >= stringStartPtr;
+      stringPtr -= 1n
+    ) {
+      let byte = WasmI32.load8U(stringPtr, 0n)
+      if ((byte & 0xC0n) == 0x80n) {
+        // We're not at the start of a codepoint, so move on
+        continue
+      }
+      if (Memory.compare(stringPtr, searchPtr, searchSize) == 0n) {
+        matchIndex = stringIndex
+        break
+      }
+      stringIndex -= 1n
+    }
+    if (matchIndex == -1n) {
+      None
+    } else {
+      Some(tagSimpleNumber(matchIndex))
+    }
+  }
+}
+
 @disableGC
 let getCodePoint = (ptr: WasmI32) => {
   // Algorithm from https://encoding.spec.whatwg.org/#utf-8-decoder

stdlib/string.md

@@ -148,7 +148,7 @@ No other changes yet.
 indexOf : (String, String) -> Option<Number>
 ```
 
-Finds the position of a substring in the input string.
+Finds the first position of a substring in the input string.
 
 Parameters:
 
@@ -169,6 +169,38 @@ Examples:
 String.indexOf("world", "Hello world") == Some(6)
 ```
 
+### String.**lastIndexOf**
+
+<details disabled>
+<summary tabindex="-1">Added in <code>next</code></summary>
+No other changes yet.
+</details>
+
+```grain
+lastIndexOf : (String, String) -> Option<Number>
+```
+
+Finds the last position of a substring in the input string.
+
+Parameters:
+
+|param|type|description|
+|-----|----|-----------|
+|`search`|`String`|The substring to find|
+|`string`|`String`|The string to inspect|
+
+Returns:
+
+|type|description|
+|----|-----------|
+|`Option<Number>`|`Some(position)` containing the starting position of the substring if found or `None` otherwise|
+
+Examples:
+
+```grain
+String.lastIndexOf("world", "Hello world world") == Some(12)
+```
+
 ### String.**charAt**
 
 <details disabled>