jt-framework/settings.gradle.kts at master · hylexus/jt-framework · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
pluginManagement {
    val defaultSpringBootBomVersion: String by settings
    plugins {
        // A Gradle plugin that provides Maven-like dependency management and exclusions
        // @see https://docs.spring.io/dependency-management-plugin/docs/1.1.7/reference/html/#getting-started
        id("io.spring.dependency-management") version "1.1.7" apply false
        id("org.springframework.boot") version defaultSpringBootBomVersion apply false
        id("io.gitee.pkmer.pkmerboot-central-publisher") version "1.1.1" apply false
    }
    repositories {
        listOf(
            "https://maven.aliyun.com/repository/public",
            "https://mirrors.cloud.tencent.com/nexus/repository/maven-public",
            "https://repo.huaweicloud.com/repository/maven",
//            "https://maven.aliyun.com/repository/gradle-plugin",
        ).forEach {
            maven {
                url = uri(it)
                name = it
                content {
                    // 上面几个镜像都没这个依赖
                    excludeGroup("net.minecraftforge.licenser")
                    excludeGroup("com.github.jk1")
                    // 排除腾讯云 404 的依赖
//                    if (it.contains("tencent")) {
//                        excludeGroup("com.github.jk1")
//                    }
                }
            }
        }
        gradlePluginPortal()
        mavenCentral()
        mavenLocal()
    }

}

// modules
include("jt-core")
include("jt-808-server-support")
include("jt-808-server-spring-boot-autoconfigure")
include("jt-808-server-spring-boot-starter-boot2")
include("jt-808-server-spring-boot-starter")
include("jt-808-server-xtream-codec-adapter")
include("jt-808-server-xtream-codec-adapter-spring-boot-starter")
include("jt-808-server-xtream-codec-adapter-spring-boot-starter-boot2")
include("jt-1078-server-support")
include("jt-1078-server-spring-boot-autoconfigure")
include("jt-1078-server-spring-boot-starter-boot2")
include("jt-1078-server-spring-boot-starter")
include("dashboard")
include("dashboard:jt-dashboard-common")
include("dashboard:jt-dashboard-server")
include("dashboard:jt-dashboard-server-spring-boot-starter")
include("dashboard:jt-dashboard-client")
include("dashboard:jt-dashboard-client-spring-boot-starter")

// samples
include("samples")
include("samples:jt-808-attachment-server-sample")
include("samples:jt-sample-common")
include("samples:jt-808-server-sample-debug")
include("samples:jt-808-server-sample-bare")
include("samples:jt-808-server-sample-bare-boot3")
include("samples:jt-808-server-sample-customized")
include("samples:jt-808-server-sample-annotation")
include("samples:jt-808-client-sample-debug")
include("samples:jt-1078-server-sample-webflux-boot3")
include("samples:jt-1078-server-sample-webmvc-boot3")
include("samples:xtream-codec-adapter-sample-boot2")
include("samples:xtream-codec-adapter-sample-boot3")

// demos
include("demos")
include("demos:jt-demo-808-server-webflux-boot3")
include("demos:jt-demo-808-server-webmvc-boot3")
include("demos:jt-demo-1078-server-webflux-boot3")
include("demos:jt-demo-1078-server-webmvc-boot3")
include("demos:jt-demo-dashboard-webflux-boot3")
include("demos:jt-demo-dashboard-webmvc-boot3")

rootProject.name = "jt-framework"

dependencyResolutionManagement {
    repositories {
        extraMavenRepositoryUrls().forEach {
            maven(it)
        }
        mavenCentral()
        mavenLocal()
    }
}

setBuildFileName(rootProject)

fun setBuildFileName(project: ProjectDescriptor) {
    project.children.forEach {
        it.buildFileName = "${it.name}.gradle.kts"
        assert(it.projectDir.isDirectory())
        assert(it.buildFile.isFile())
        setBuildFileName(it)
    }
}

fun extraMavenRepositoryUrls() = listOf(
    // "https://mirrors.cloud.tencent.com/nexus/repository/maven-public",
    // "https://repo.huaweicloud.com/repository/maven",
    "https://maven.aliyun.com/repository/central",
    "https://maven.aliyun.com/repository/public",
    "https://maven.aliyun.com/repository/google",
    "https://maven.aliyun.com/repository/spring",
    // Central
    "https://repo1.maven.org/maven2",
    "https://maven.aliyun.com/repository/spring-plugin",
    "https://maven.aliyun.com/repository/gradle-plugin",
    "https://maven.aliyun.com/repository/grails-core",
    "https://maven.aliyun.com/repository/apache-snapshots",
    "https://plugins.gradle.org/m2/",
    // "https://repo.spring.io/release",
    // "https://repo.spring.io/snapshot"
)