build.gradle

/*
 * Licensed to the Apache Software Foundation (ASF) under one or more
 * contributor license agreements.  See the NOTICE file distributed with
 * this work for additional information regarding copyright ownership.
 * The ASF licenses this file to You under the Apache License, Version 2.0
 * (the "License"); you may not use this file except in compliance with
 * the License.  You may obtain a copy of the License at
 *
 *      http://www.apache.org/licenses/LICENSE-2.0
 *
 * Unless required by applicable law or agreed to in writing, software
 * distributed under the License is distributed on an "AS IS" BASIS,
 * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
 * See the License for the specific language governing permissions and
 * limitations under the License.
 */

plugins {
    id "com.github.hierynomus.license" version "0.16.1" apply false
    id "com.github.jk1.dependency-license-report" version "3.1.2"
}

subprojects {
    apply plugin: "com.github.hierynomus.license-base"

    //for subprojects header can be found in top-level project.
    license.header = file('../header.txt')

    license.exclude("*.xml");

}

tasks.register("license") {
    group = "License"
    description = "Checks for header consistency."
    dependsOn subprojects.collect { it.tasks.matching { task -> task.name in ["licenseMain", "licenseTest"] } }
}

tasks.register("licenseFormat") {
    group = "License"
    description = "Applies the license found in the header file in files missing the header."
    dependsOn subprojects.collect { it.tasks.matching { task -> task.name in ["licenseFormatMain", "licenseFormatTest"] } }
}

allprojects {
    apply plugin: 'java-library'

    java {
        toolchain {
            languageVersion = JavaLanguageVersion.of(17)
        }
    }

    ext {

        jettyVer = '12.1.8'

        ignVer = '2.18.0'

        guavaVer = '33.6.0-jre'

        // Logback is dual licensed. For ASF compatibility this build uses the EPL v1.0 choice
        // for binary convenience packages; the LGPL option is not selected.
        logbackVer = '1.5.32'

        // MIT/X11 license, category A;
        slf4jVer = '2.0.17'

        gsonVer = '2.14.0'

        junitVer = '4.13.2'
        mockitoVer = '5.23.0'
        jerseyVer = '2.48'
        guiceVer = '5.1.0'
        snappyVer = '1.1.10.8'
        jaxbVer = '2.3.9'
        mailVer = '1.6.2'
        checkerQualVer = '4.0.0'
        jsr305Ver = '3.0.2'

        igniteJava17JvmArgs = [
            "-XX:+IgnoreUnrecognizedVMOptions",
            "--add-exports=java.base/jdk.internal.misc=ALL-UNNAMED",
            "--add-exports=java.base/sun.nio.ch=ALL-UNNAMED",
            "--add-exports=java.management/com.sun.jmx.mbeanserver=ALL-UNNAMED",
            "--add-exports=jdk.internal.jvmstat/sun.jvmstat.monitor=ALL-UNNAMED",
            "--add-exports=java.base/sun.reflect.generics.reflectiveObjects=ALL-UNNAMED",
            "--add-opens=java.base/java.io=ALL-UNNAMED",
            "--add-opens=java.base/java.lang=ALL-UNNAMED",
            "--add-opens=java.base/java.nio=ALL-UNNAMED",
            "--add-opens=java.base/java.time=ALL-UNNAMED",
            "--add-opens=java.base/java.util=ALL-UNNAMED",
            "--add-opens=java.base/java.util.concurrent=ALL-UNNAMED",
            "--add-opens=java.base/sun.nio.ch=ALL-UNNAMED"
        ]
    }

    repositories {
        //uncomment for RC testing
        //    maven {
        //      url "https://repository.apache.org/content/repositories/orgapacheignite-1552/"
        //    }

        mavenCentral()
        mavenLocal()
    }

    tasks.withType(JavaExec).configureEach {
        jvmArgs igniteJava17JvmArgs
    }

    tasks.withType(JavaCompile).configureEach {
        options.compilerArgs += ['-Xlint:deprecation', '-Xlint:unchecked']
    }
}

/*
license {
  //  header = file('header.txt')

    mapping {
        javascript='JAVADOC_STYLE'
    }
}*/