gobuild.nix/package.nix at main · katexochen/gobuild.nix · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
{
  pkgs ?
    let
      flakeLock = builtins.fromJSON (builtins.readFile ./flake.lock);
      inherit (flakeLock.nodes.nixpkgs) locked;
    in
    import (builtins.fetchTree locked) { },
}:

let

  # Go package set containing build cache output & hooks
  goPackages = pkgs.callPackages ./go-pkgs.nix { };

in
{
  inherit goPackages;

  fsnotify =
    let
      base = goPackages."github.com/fsnotify/fsnotify";
    in
    pkgs.stdenv.mkDerivation {
      pname = "fsnotify";
      inherit (base) version src;

      postPatch = ''
        cd ${base.pname}@v${base.version}
      '';

      buildInputs = [
        goPackages."golang.org/x/sys"
      ];

      nativeBuildInputs = [ goPackages.hooks.makeGoBinary ];
    };

  simple-package = pkgs.stdenv.mkDerivation (finalAttrs: {
    name = "simple-package";

    src = ./fixtures/simple-package;

    nativeBuildInputs = [ goPackages.hooks.makeGoBinary ];

    buildInputs = [
      goPackages."github.com/alecthomas/kong"
    ];
  });

  keep-sorted = pkgs.stdenv.mkDerivation (finalAttrs: {
    pname = "keep-sorted";
    version = "0.6.0";

    src = pkgs.fetchFromGitHub {
      owner = "google";
      repo = "keep-sorted";
      tag = "v${finalAttrs.version}";
      hash = "sha256-ROvj7w8YMq6+ntx0SWi+HfN4sO6d7RjKWwlb/9gfz8w=";
    };

    postPatch = ''
      substituteInPlace main.go \
        --replace-fail 'readVersion())' '"v${finalAttrs.version}")'
    '';

    nativeBuildInputs = [ goPackages.hooks.makeGoBinary ];

    buildInputs = [
      goPackages."github.com/Workiva/go-datastructures"
      goPackages."github.com/google/go-cmp"
      goPackages."github.com/mattn/go-isatty"
      goPackages."github.com/rs/zerolog"
      goPackages."github.com/spf13/pflag"
      goPackages."gopkg.in/yaml.v3"
    ];

    nativeInstallCheckInputs = [ pkgs.versionCheckHook ];

    doInstallCheck = true;
  });
}