Make building SSE events more closely match the spec

Also add many more tests.

Author: essen

src/cow_sse.erl

@@ -301,7 +301,8 @@ event_comment(_) ->
 	[].
 
 event_id(#{id := ID}) ->
-	nomatch = binary:match(iolist_to_binary(ID), <<"\n">>),
+	nomatch = binary:match(iolist_to_binary(ID),
+		[<<"\r\n">>, <<"\r">>, <<"\n">>]),
 	[<<"id: ">>, ID, $\n];
 event_id(_) ->
 	[].
@@ -311,7 +312,8 @@ event_name(#{event := Name0}) ->
 		is_atom(Name0) -> atom_to_binary(Name0, utf8);
 		true -> iolist_to_binary(Name0)
 	end,
-	nomatch = binary:match(Name, <<"\n">>),
+	nomatch = binary:match(Name,
+		[<<"\r\n">>, <<"\r">>, <<"\n">>]),
 	[<<"event: ">>, Name, $\n];
 event_name(_) ->
 	[].
@@ -327,7 +329,8 @@ event_retry(_) ->
 	[].
 
 prefix_lines(IoData, Prefix) ->
-	Lines = binary:split(iolist_to_binary(IoData), <<"\n">>, [global]),
+	Lines = binary:split(iolist_to_binary(IoData),
+		[<<"\r\n">>, <<"\r">>, <<"\n">>], [global]),
 	[[Prefix, <<": ">>, Line, $\n] || Line <- Lines].
 
 -ifdef(TEST).
@@ -345,5 +348,60 @@ event_test() ->
 	_ = event(#{retry => 5000}),
 	_ = event(#{event => "test", data => "test"}),
 	_ = event(#{id => "test", event => "test", data => "test"}),
+	_ = event(#{data => "test\r\ntest"}),
+	_ = event(#{data => "test\rtest\r"}),
+	_ = event(#{data => "test\ntest"}),
 	ok.
+
+event_error_test() ->
+	{'EXIT', _} = (catch event(#{id => "test\n"})),
+	{'EXIT', _} = (catch event(#{id => "test\r"})),
+	{'EXIT', _} = (catch event(#{id => "test\r\n"})),
+	{'EXIT', _} = (catch event(#{event => "test\n"})),
+	{'EXIT', _} = (catch event(#{event => "test\r"})),
+	{'EXIT', _} = (catch event(#{event => "test\r\n"})),
+	ok.
+
+identity_test_() ->
+	Tests = [
+		#{data => <<"hello">>},
+		#{event => <<"update">>, data => <<"hello">>},
+		#{id => <<"42">>, data => <<"hello">>},
+		#{data => <<"a\nb">>},
+		#{data => <<"multi\nline\ndata">>},
+		#{event => <<"update">>, data => <<"hello">>},
+		#{id => <<"abc">>, data => <<"x">>},
+		#{comment => <<"c1">>, data => <<"d1">>, event => <<"e1">>, id => <<"i1">>},
+		#{data => <<>>},
+		#{data => <<"data with trailing newline\n">>},
+		#{data => <<"\n">>},
+		#{data => <<"\n\n">>},
+		#{data => <<"">>, id => <<"1">>},
+		#{data => <<"z">>},
+		#{id => <<"17">>},
+		#{data => << <<$a>> || _ <- lists:seq(1,200) >>},
+		#{data => <<"こんにちは世界">>},
+		#{retry => 30000, data => <<"reconnect">>}
+	],
+	[{lists:flatten(io_lib:format("~0p", [V])),
+		fun() -> true = do_identity_result(V) =:= do_identity_build_parse(V) end}
+			|| V <- Tests].
+
+do_identity_build_parse(Event) ->
+	{event, Parsed, _} = parse(iolist_to_binary(event(Event)), init()),
+	case Parsed of
+		#{data := Data} -> Parsed#{data => iolist_to_binary(Data)};
+		_ -> Parsed
+	end.
+
+do_identity_result(E=#{id := ID}) when map_size(E) =:= 1 ->
+	#{
+		last_event_id => ID
+	};
+do_identity_result(Event) ->
+	#{
+		event_type => maps:get(event, Event, <<"message">>),
+		data => maps:get(data, Event, <<>>),
+		last_event_id => maps:get(id, Event, <<>>)
+	}.
 -endif.