feat: add flake-parts installer image options

Author: different-name

flake-module.nix

@@ -1,43 +1,162 @@
-{ lib, ... }:
 {
-  options.flake.diskoConfigurations = lib.mkOption {
-    type = lib.types.lazyAttrsOf lib.types.raw;
-    default = { };
-    description = "Instantiated Disko configurations. Used by `disko` and `disko-install`.";
-    example = {
-      my-pc = {
-        disko.devices = {
-          disk = {
-            my-disk = {
-              device = "/dev/sda";
-              type = "disk";
-              content = {
-                type = "gpt";
-                partitions = {
-                  ESP = {
-                    type = "EF00";
-                    size = "500M";
-                    content = {
-                      type = "filesystem";
-                      format = "vfat";
-                      mountpoint = "/boot";
-                      mountOptions = [ "umask=0077" ];
-                    };
-                  };
-                  root = {
-                    size = "100%";
-                    content = {
-                      type = "filesystem";
-                      format = "ext4";
-                      mountpoint = "/";
+  lib,
+  config,
+  inputs,
+  self,
+  ...
+}:
+let
+  inherit (lib)
+    mkOption
+    types
+    ;
+
+  nixpkgs = inputs.nixpkgs or (throw "No nixpkgs input found");
+
+  flakeOutPaths =
+    let
+      collector =
+        parent:
+        map (
+          child:
+          [ child.outPath ] ++ (if child ? inputs && child.inputs != { } then (collector child) else [ ])
+        ) (lib.attrValues parent.inputs);
+    in
+    lib.unique (lib.flatten (collector self));
+
+  mkInstallClosureModule =
+    nixosConfiguration:
+    { pkgs, ... }:
+    let
+      dependencies = [
+        nixosConfiguration.config.system.build.toplevel
+        nixosConfiguration.config.system.build.diskoScript
+        nixosConfiguration.config.system.build.diskoScript.drvPath
+        nixosConfiguration.pkgs.stdenv.drvPath
+
+        # https://github.com/NixOS/nixpkgs/blob/f2fd33a198a58c4f3d53213f01432e4d88474956/nixos/modules/system/activation/top-level.nix#L342
+        nixosConfiguration.pkgs.perlPackages.ConfigIniFiles
+        nixosConfiguration.pkgs.perlPackages.FileSlurp
+
+        (nixosConfiguration.pkgs.closureInfo { rootPaths = [ ]; }).drvPath
+      ]
+      ++ flakeOutPaths;
+
+      closureInfo = pkgs.closureInfo { rootPaths = dependencies; };
+    in
+    {
+      environment.etc."install-closure".source = "${closureInfo}/store-paths";
+    };
+in
+{
+  options = {
+    flake.diskoConfigurations = mkOption {
+      type = types.lazyAttrsOf types.raw;
+      default = { };
+      description = "Instantiated Disko configurations. Used by `disko` and `disko-install`.";
+      example = lib.literalExpression ''
+        {
+          my-pc = {
+            disko.devices = {
+              disk = {
+                my-disk = {
+                  device = "/dev/sda";
+                  type = "disk";
+                  content = {
+                    type = "gpt";
+                    partitions = {
+                      ESP = {
+                        type = "EF00";
+                        size = "500M";
+                        content = {
+                          type = "filesystem";
+                          format = "vfat";
+                          mountpoint = "/boot";
+                          mountOptions = [ "umask=0077" ];
+                        };
+                      };
+                      root = {
+                        size = "100%";
+                        content = {
+                          type = "filesystem";
+                          format = "ext4";
+                          mountpoint = "/";
+                        };
+                      };
                     };
                   };
                 };
               };
             };
           };
-        };
+        }'';
+    };
+
+    disko.nixosImages = {
+      hosts = mkOption {
+        type = types.attrsOf (
+          types.submodule (
+            { name, ... }:
+            {
+              options = {
+                nixosConfiguration = mkOption {
+                  type = types.str;
+                  default = name;
+                  defaultText = lib.literalExpression "<name>";
+                  description = "Flake attribute for NixOS Configuration to install.";
+                  example = "my-host";
+                };
+
+                formats = mkOption {
+                  type = types.listOf types.str; # TODO stricter typing
+                  apply = lib.unique;
+                  default = [ "iso-installer" ];
+                  description = "Image formats to generate installer images for.";
+                  example = "hyperv";
+                };
+
+                modules = mkOption {
+                  type = types.listOf types.deferredModule;
+                  default = [ ];
+                  description = "NixOS modules to include in the installer configuration.";
+                  example = lib.literalExpression ''
+                    { pkgs, ... }:
+                    {
+                      environment.systemPackages = [
+                        (pkgs.writeShellScriptBin "install-nixos-unattended" ''''
+                          set -eux
+                          # Replace "/dev/disk/by-id/some-disk-id" with your actual disk ID
+                          exec ''${pkgs.disko}/bin/disko-install --flake "''${self}#your-machine" --disk vdb "/dev/disk/by-id/some-disk-id"
+                        '''')
+                      ];
+                    }'';
+                };
+              };
+            }
+          )
+        );
       };
     };
   };
+
+  config.flake.packages = lib.mkMerge (
+    lib.concatLists (
+      lib.mapAttrsToList (
+        name: host:
+        let
+          nixosConfiguration = self.nixosConfigurations.${host.nixosConfiguration};
+          inherit (nixosConfiguration.pkgs.stdenv.hostPlatform) system;
+
+          installerConfiguration = nixpkgs.lib.nixosSystem {
+            inherit (nixosConfiguration.pkgs.stdenv.hostPlatform) system;
+            modules = [ (mkInstallClosureModule nixosConfiguration) ] ++ host.modules;
+          };
+        in
+        map (format: {
+          ${system}."disko-image-${name}-${format}" =
+            installerConfiguration.config.system.build.images.${format};
+        }) host.formats
+      ) config.disko.nixosImages.hosts
+    )
+  );
 }