ALGT2/src/Assets/TestLanguages/STFL.language at master · pietervdvn/ALGT2 · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
import ALGT.Builtins

 STFL
******

# A simply typed functional language; mainly used for testing purposes

 Syntax
========

baseType	::= "Bool" | "Int" | "(" type ")"
type		::= baseType "->" type | baseType

bool	::= "True" | "False"

var	::= Identifier

lambda	::= "(" "\\" var ":" type "." expr ")"

canon	::= bool | integer | var | lambda

baseExpr ::= canon | "(" expr ")" | "If" expr "Then" expr "Else" expr

intOp	::= "+"
boolOp	::= "&"
sameOp	::= "="

op	::= intOp | boolOp | sameOp

expr	::= baseExpr op expr | baseExpr expr| baseExpr

typingEnv	::= var ":" type typingEnv | "[]"


 Functions
===========

not	: bool -> bool
not("True")	= "False"
not("False")	= "True"


and	: bool * bool -> bool
and("True", "True")	= "True"
and(_, _)		= "False"


# Searches the typing environment
search	: var * typingEnv -> type
search(x, x ":" t _)
	= t
search(x, _ _ _ te)
	= search(x, te)


typeEq	: type * type -> type
typeEq(t, t)
	= t
typeEq("(" t ")", t)
	= t
typeEq(t, "(" t ")")
	= t
typeEq(ta0 "->" tr0, ta1 "->" tr1)
	= typeEq(ta0, ta1) "->" typeEq(tr0, tr1)


subs	: var * expr * expr -> expr
subs(x, x, replacement)
	= replacement
subs(x, "(" "\\" x ":" type "." expr ")", _)
	= "(" "\\" x ":" type "." expr ")"
subs(x, "(" expr ")", replacement)
	= "(" subs(x, expr, replacement) ")"
subs(x, expr0 op expr1, replacement)
	= subs(x, expr0, replacement) op subs(x, expr1, replacement)
subs(x, "If" cond "Then" exprT "Else" exprF, replacement)
	= "If" subs(x, cond, replacement) "Then" subs(x, exprT, replacement) "Else" subs(x, exprF, replacement)


 Relations
===========

(→)	: expr (in) * expr (out)

(::) : expr (in) * type (out) ; Pronounced as "empty env"
(⊢) : typingEnv (in) * expr (in) * type (out)

 Rules
========


----------------------------------------------------------------- [EApp]
 (→) ("(" "\\" x ":" typeDom "." expr ")") arg, subs(x, arg, expr)


------------------------------ [EPar]
 (→) "(" expr ")", expr


 expr0 : bool	expr1 : bool
------------------------------------------ [EBoolAnd]
 (→) expr0 "&" expr1, and(expr0, expr1)


 expr0 : integer	expr1 : integer
------------------------------------------ [EIntPlus]
 (→) expr0 "+" expr1, plus(expr0, expr1)


----------------------------------------- [EIfTrue]
 (→) "If" "True" "Then" e0 "Else" e1, e0


----------------------------------------- [EIfFalse]
 (→) "If" "False" "Then" e0 "Else" e1, e1


### ------------------------- Rules about Typing ---------------------


 (⊢) "[]", expr, type
---------------------- [ Type in empty environment ]
 (::) expr, type


 expr : bool
---------------------- [TTrue]
 (⊢) _, expr, "Bool"


 expr : integer
---------------------- [TNumber]
 (⊢) _, expr, "Int"


 x : var
----------------------------- [TVar]
 (⊢) env, x, search(x, env)


 (⊢) x ":" typeDom env, expr, typeCod
-------------------------------------------------------------------- [TLambda]
 (⊢) env, "(" "\\" x ":" typeDom "." expr ")", typeDom "->" typeCod


 (⊢) env, f, tDom "->" tCod	(⊢) env, arg, tArg
------------------------------------------------------- [TApp]
 (⊢) env, f arg, typeEq(tCod, tArg)


 (⊢) env, expr, type
------------------------------ [TPar]
 (⊢) env, "(" expr ")", type


 (⊢) env, expr0, "Bool"	(⊢) env, expr1, "Bool"		op : boolOp
---------------------------------------------------------------------------- [TBoolInfix]
 (⊢) env, expr0 op expr1, "Bool"


 (⊢) env, expr0, "Int"		(⊢) env, expr1, "Int"		op : intOp
---------------------------------------------------------------------------- [TIntInfix]
 (⊢) env, expr0 op expr1, "Int"


 (⊢) env, expr0, t0	(⊢) env, expr1, t1
-------------------------------------------- [TSameInfix]
 (⊢) env, expr0 op expr1, typeEq(t0, t1)


 (⊢) env, cond, "Bool"		(⊢) env, e0, t0		(⊢) env, e1, t1
--------------------------------------------------------------------------------- [TIf]
 (⊢) env, "If" cond "Then" e0 "Else" e1, typeEq(t0, t1)