Add test enabling all feature flags with exchange logger

Add a test enabling all stable feature flags with exchange logging enabled.

This is a more general test case for #11652
that should catch all future feature flag issues when `rabbit_ff_controller` publishes a message.

Relates
#11652
#14069
#14796

Author: ansd

deps/rabbit/test/logging_SUITE.erl

@@ -54,6 +54,7 @@
          logging_to_exchange_works/1,
          update_log_exchange_config/1,
          use_exchange_logger_when_enabling_khepri_db/1,
+         use_exchange_logger_when_enabling_all_feature_flags/1,
 
          logging_to_syslog_works/1]).
 
@@ -101,7 +102,8 @@ groups() ->
      {exchange_output, [],
       [logging_to_exchange_works,
        update_log_exchange_config,
-       use_exchange_logger_when_enabling_khepri_db]},
+       use_exchange_logger_when_enabling_khepri_db,
+       use_exchange_logger_when_enabling_all_feature_flags]},
 
      {syslog_output, [],
       [logging_to_syslog_works]}
@@ -151,8 +153,6 @@ init_per_testcase(Testcase, Config) ->
         %% The exchange output requires RabbitMQ to run. All testcases in this
         %% group will run in the context of that RabbitMQ node.
         exchange_output ->
-            ExchProps = [{enabled, true},
-                         {level, debug}],
             Config1 = rabbit_ct_helpers:set_config(
                         Config,
                         [{rmq_nodename_suffix, Testcase}]),
@@ -162,15 +162,29 @@ init_per_testcase(Testcase, Config) ->
                                 Config1,
                                 [{rmq_nodes_count, 3},
                                  {metadata_store, mnesia}]);
+                          use_exchange_logger_when_enabling_all_feature_flags ->
+                              rabbit_ct_helpers:set_config(
+                                Config1,
+                                [{rmq_nodes_count, 3}]);
                           _ ->
                               rabbit_ct_helpers:set_config(
                                 Config1,
                                 [{rmq_nodes_count, 1}])
                       end,
-            Config3 = rabbit_ct_helpers:merge_app_env(
-                        Config2,
-                        {rabbit, [{log, [{exchange, ExchProps},
-                                         {file, [{level, debug}]}]}]}),
+            LogCfg = {log, [
+                            {exchange, [{enabled, true}, {level, debug}]},
+                            {file, [{level, debug}]}
+                           ]},
+            Config3 = case Testcase of
+                          use_exchange_logger_when_enabling_all_feature_flags ->
+                              rabbit_ct_helpers:merge_app_env(
+                                Config2, {rabbit, [LogCfg,
+                                                   {forced_feature_flags_on_init, []}
+                                                  ]});
+                          _ ->
+                              rabbit_ct_helpers:merge_app_env(
+                                Config2, {rabbit, [LogCfg]})
+                      end,
             rabbit_ct_helpers:run_steps(
               Config3,
               rabbit_ct_broker_helpers:setup_steps() ++
@@ -1122,6 +1136,50 @@ use_exchange_logger_when_enabling_khepri_db(Config) ->
        ok,
        rabbit_ct_broker_helpers:enable_feature_flag(Config, khepri_db)).
 
+%% Test case for https://github.com/rabbitmq/rabbitmq-server/discussions/11652
+use_exchange_logger_when_enabling_all_feature_flags(Config) ->
+    {Conn, Chan} = rabbit_ct_client_helpers:open_connection_and_channel(Config),
+
+    #'queue.declare_ok'{} = amqp_channel:call(
+                              Chan, #'queue.declare'{queue = <<"cq">>,
+                                                     durable = true,
+                                                     arguments = [{<<"x-queue-type">>, longstr, <<"classic">>}]
+                                                    }),
+    #'queue.declare_ok'{} = amqp_channel:call(
+                              Chan, #'queue.declare'{queue = <<"qq">>,
+                                                     durable = true,
+                                                     arguments = [{<<"x-queue-type">>, longstr, <<"quorum">>}]
+                                                    }),
+    #'queue.declare_ok'{} = amqp_channel:call(
+                              Chan, #'queue.declare'{queue = <<"sq">>,
+                                                     durable = true,
+                                                     arguments = [{<<"x-queue-type">>, longstr, <<"stream">>}]
+                                                    }),
+    [#'queue.bind_ok'{} = amqp_channel:call(
+                            Chan, #'queue.bind'{queue = QName,
+                                                exchange =  <<"amq.rabbitmq.log">>,
+                                                routing_key = <<"#">>}) ||
+     QName <- [<<"cq">>, <<"qq">>, <<"sq">>]],
+
+    %% Sanity check that there is at least one disabled stable feature flag.
+    DisabledFFsBefore = rabbit_ct_broker_helpers:rpc(Config, rabbit_feature_flags, list, [disabled, stable]),
+    ?assertNotEqual(0, maps:size(DisabledFFsBefore)),
+
+    ?assertEqual(ok, rabbit_ct_broker_helpers:rpc(Config, rabbit_feature_flags, enable_all, [stable])),
+
+    DisabledFFsAfter = rabbit_ct_broker_helpers:rpc(Config, rabbit_feature_flags, list, [disabled, stable]),
+    ?assertEqual(0, maps:size(DisabledFFsAfter)),
+
+    #'queue.delete_ok'{message_count = CountCQ} = amqp_channel:call(Chan, #'queue.delete'{queue = <<"cq">>}),
+    #'queue.delete_ok'{message_count = CountQQ} = amqp_channel:call(Chan, #'queue.delete'{queue = <<"qq">>}),
+    #'queue.delete_ok'{} = amqp_channel:call(Chan, #'queue.delete'{queue = <<"sq">>}),
+    %% We expect that some log messages ended up in the queues since rabbit_ff_controller does some logging
+    %% when enabling all feature flags.
+    ?assertNotEqual(0, CountCQ),
+    ?assertNotEqual(0, CountQQ),
+
+    rabbit_ct_client_helpers:close_connection_and_channel(Conn, Chan).
+
 logging_to_syslog_works(Config) ->
     Context = default_context(Config),
     ok = application:set_env(