Avoid list allocation of lists:filter/2

In the common case no MA entries need to removed.
This commit saves a list allocation for the common case.

(When reading from a stream, x-exchange or x-routing-key should make
`lists:all/2` return immediately because these two message annotations
will be prepended before writing to the stream.)

Author: ansd

deps/rabbit/src/mc_amqp.erl

@@ -472,45 +472,50 @@ convert_from_3_13_msg(#msg{header = H,
 
 -spec protocol_state_message_annotations(amqp_annotations(), mc:annotations()) ->
     amqp_annotations().
-protocol_state_message_annotations(MA0, Anns) ->
-    %% filter all MA's that are going to be overwritten by ANNS
-    MA = lists:filter(
-           fun
-               ({{symbol, <<"x-exchange">>}, _}) ->
-                   not maps:is_key(?ANN_EXCHANGE, Anns);
-               ({{symbol, <<"x-routing-key">>}, _}) ->
-                   not maps:is_key(?ANN_ROUTING_KEYS, Anns);
-               ({{symbol, <<"x-opt-rabbitmq-received-time">>}, _}) ->
-                   not maps:is_key(<<"timestamp_in_ms">>, Anns);
-               ({{symbol, <<"x-opt-deaths">>}, _}) ->
-                   not maps:is_key(deaths, Anns);
-               ({{symbol, <<"x-", _/binary>> = K}, _}) ->
-                   not maps:is_key(K, Anns);
-               (_) ->
-                   true
-           end, MA0),
-
-    maps:fold(
-      fun(?ANN_EXCHANGE, Exchange, L) ->
-              [{{symbol, <<"x-exchange">>}, {utf8, Exchange}} | L];
-         (?ANN_ROUTING_KEYS, RKeys, L) ->
-              RKey = hd(RKeys),
-              [{{symbol, <<"x-routing-key">>}, {utf8, RKey}} | L];
-         (<<"x-", _/binary>> = K, V, L)
-           when V =/= undefined ->
-              %% any x-* annotations get added as message annotations
-              [{{symbol, K}, mc_util:infer_type(V)} | L];
-         (<<"timestamp_in_ms">>, V, L) ->
-              [{{symbol, <<"x-opt-rabbitmq-received-time">>},
-                {timestamp, V}} | L];
-         (deaths, Deaths, L)
-           when is_list(Deaths) ->
-              Maps = encode_deaths(Deaths),
-              [{{symbol, <<"x-opt-deaths">>},
-                {array, map, Maps}} | L];
-         (_, _, Acc) ->
-              Acc
-      end, MA, Anns).
+protocol_state_message_annotations(MA, Anns) ->
+    %% To efficiently overwrite MA with Anns, we first remove entries in MA
+    %% that will be re-added by Anns. We optimise for the common case where no
+    %% MA entries need to be removed.
+    Fun = fun({{symbol, <<"x-exchange">>}, _}) ->
+                  not maps:is_key(?ANN_EXCHANGE, Anns);
+             ({{symbol, <<"x-routing-key">>}, _}) ->
+                  not maps:is_key(?ANN_ROUTING_KEYS, Anns);
+             ({{symbol, <<"x-opt-rabbitmq-received-time">>}, _}) ->
+                  not maps:is_key(<<"timestamp_in_ms">>, Anns);
+             ({{symbol, <<"x-opt-deaths">>}, _}) ->
+                  not maps:is_key(deaths, Anns);
+             ({{symbol, <<"x-", _/binary>> = K}, _}) ->
+                  not maps:is_key(K, Anns);
+             (_) ->
+                  true
+          end,
+    MA1 = case lists:all(Fun, MA) of
+              true ->
+                  MA;
+              false ->
+                  lists:filter(Fun, MA)
+          end,
+
+    maps:fold(fun(?ANN_EXCHANGE, Exchange, L) ->
+                      [{{symbol, <<"x-exchange">>}, {utf8, Exchange}} | L];
+                 (?ANN_ROUTING_KEYS, RKeys, L) ->
+                      RKey = hd(RKeys),
+                      [{{symbol, <<"x-routing-key">>}, {utf8, RKey}} | L];
+                 (<<"x-", _/binary>> = K, V, L)
+                   when V =/= undefined ->
+                      %% any x-* annotations get added as message annotations
+                      [{{symbol, K}, mc_util:infer_type(V)} | L];
+                 (<<"timestamp_in_ms">>, V, L) ->
+                      [{{symbol, <<"x-opt-rabbitmq-received-time">>},
+                        {timestamp, V}} | L];
+                 (deaths, Deaths, L)
+                   when is_list(Deaths) ->
+                      Maps = encode_deaths(Deaths),
+                      [{{symbol, <<"x-opt-deaths">>},
+                        {array, map, Maps}} | L];
+                 (_, _, Acc) ->
+                      Acc
+              end, MA1, Anns).
 
 encode(Sections) when is_list(Sections) ->
     [amqp10_framing:encode_bin(Section) || Section <- Sections,