tidal-discord/Setup-full-X64.nsi at master · ricardag/tidal-discord · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
# Uses NSIS Installer 3.0
# http://nsis.sourceforge.net/
#
!include "MUI.nsh"
!include "nsProcess.nsh"

Name "TIDAL Rich Presence for Discord"

outFile "TIDAL-Discord-setup-full-X64.exe"
InstallDir "$PROGRAMFILES64\@ricardag\TIDAL Rich Presence for Discord"
RequestExecutionLevel admin ;Require admin rights on NT6+ (When UAC is turned on)

!define MUI_ICON "TidalDiscord\tidal.ico"
!define MUI_UNICON "TidalDiscord\tidal.ico"

!insertmacro MUI_PAGE_WELCOME
!insertmacro MUI_PAGE_DIRECTORY
!insertmacro MUI_PAGE_INSTFILES
!insertmacro MUI_PAGE_FINISH

!insertmacro MUI_UNPAGE_CONFIRM
!insertmacro MUI_UNPAGE_INSTFILES

!insertmacro MUI_LANGUAGE "English"


!macro TerminateApp
	${nsProcess::FindProcess} "TidalDiscord.exe" $R0

	${If} $R0 == 0
		DetailPrint "'TIDAL Rich Presence for Discord' is running. Closing it down"
		${nsProcess::CloseProcess} "TidalDiscord.exe" $R0
		DetailPrint "Waiting for 'TIDAL Rich Presence for Discord' to close"
		Sleep 2000
	${Else}
		DetailPrint "'TIDAL Rich Presence for Discord' was not found to be running"
	${EndIf}

	${nsProcess::Unload}
!macroend


Section "install"
	!insertmacro TerminateApp

	setOutPath $INSTDIR
	writeUninstaller $INSTDIR\uninstaller.exe
	File "TidalDiscord\tidal.ico"
	File "TidalDiscord\bin\Release\net6.0-windows\publish\win-x64\*.*"

	# Startup
	CreateShortCut "$DESKTOP\TIDAL Rich Presence for Discord.lnk" "$INSTDIR\TidalDiscord.exe" "" "$INSTDIR\tidal.ico" 0

	WriteRegStr HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\TIDAL Rich Presence for Discord" "DisplayName" "TIDAL Rich Presence for Discord"
	WriteRegStr HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\TIDAL Rich Presence for Discord" "UninstallString" "$INSTDIR\uninstaller.exe"
	WriteRegStr HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\TIDAL Rich Presence for Discord" "Publisher" "@ricardag"
	WriteRegStr HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\TIDAL Rich Presence for Discord" "DisplayIcon" "$INSTDIR\TidalDiscord.exe"


	# Runs app
	Exec '$INSTDIR\TidalDiscord.exe'
SectionEnd

Section "Uninstall"
	!insertmacro TerminateApp

	delete "$DESKTOP\TIDAL Rich Presence for Discord.lnk"

	delete "$INSTDIR\*.*"
	RmDir  $INSTDIR

	DeleteRegKey HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\TIDAL Rich Presence for Discord"
SectionEnd