Allow the user to Add and Delete OpenGraphObjects

Author: venriq

lib/og_catalog/open_graph_objects.ex

@@ -0,0 +1,105 @@
+defmodule OgCatalog.OpenGraphObjects do
+  @moduledoc """
+  The OpenGraphObjects context.
+  """
+
+  import Ecto.Query, warn: false
+  alias OgCatalog.Repo
+
+  alias OgCatalog.OpenGraphObjects.OpenGraphObject
+
+  @doc """
+  Returns the list of open_graph_objects.
+
+  ## Examples
+
+      iex> list_open_graph_objects()
+      [%OpenGraphObject{}, ...]
+
+  """
+  def list_open_graph_objects do
+    from(o in OpenGraphObject, order_by: [desc: o.inserted_at])
+    |> Repo.all()
+  end
+
+  @doc """
+  Gets a single open_graph_object.
+
+  Raises `Ecto.NoResultsError` if the Open graph object does not exist.
+
+  ## Examples
+
+      iex> get_open_graph_object!(123)
+      %OpenGraphObject{}
+
+      iex> get_open_graph_object!(456)
+      ** (Ecto.NoResultsError)
+
+  """
+  def get_open_graph_object!(id), do: Repo.get!(OpenGraphObject, id)
+
+  @doc """
+  Creates an open_graph_object.
+
+  ## Examples
+
+      iex> create_open_graph_object(%{field: value})
+      {:ok, %OpenGraphObject{}}
+
+      iex> create_open_graph_object(%{field: bad_value})
+      {:error, %Ecto.Changeset{}}
+
+  """
+  def create_open_graph_object(attrs) do
+    %OpenGraphObject{}
+    |> OpenGraphObject.changeset(attrs)
+    |> Repo.insert()
+  end
+
+  @doc """
+  Updates an open_graph_object.
+
+  ## Examples
+
+      iex> update_open_graph_object(open_graph_object, %{field: new_value})
+      {:ok, %OpenGraphObject{}}
+
+      iex> update_open_graph_object(open_graph_object, %{field: bad_value})
+      {:error, %Ecto.Changeset{}}
+
+  """
+  def update_open_graph_object(%OpenGraphObject{} = open_graph_object, attrs) do
+    open_graph_object
+    |> OpenGraphObject.update_changeset(attrs)
+    |> Repo.update()
+  end
+
+  @doc """
+  Deletes an open_graph_object.
+
+  ## Examples
+
+      iex> delete_open_graph_object(open_graph_object)
+      {:ok, %OpenGraphObject{}}
+
+      iex> delete_open_graph_object(open_graph_object)
+      {:error, %Ecto.Changeset{}}
+
+  """
+  def delete_open_graph_object(%OpenGraphObject{} = open_graph_object) do
+    Repo.delete(open_graph_object)
+  end
+
+  @doc """
+  Returns an `%Ecto.Changeset{}` for tracking open_graph_object changes.
+
+  ## Examples
+
+      iex> change_open_graph_object(open_graph_object)
+      %Ecto.Changeset{data: %OpenGraphObject{}}
+
+  """
+  def change_open_graph_object(%OpenGraphObject{} = open_graph_object, attrs \\ %{}) do
+    OpenGraphObject.changeset(open_graph_object, attrs)
+  end
+end

lib/og_catalog/open_graph_objects/open_graph_object.ex

@@ -0,0 +1,31 @@
+defmodule OgCatalog.OpenGraphObjects.OpenGraphObject do
+  use Ecto.Schema
+  import Ecto.Changeset
+
+  @primary_key {:id, :binary_id, autogenerate: true}
+  @foreign_key_type :binary_id
+  schema "open_graph_objects" do
+    field :page_url, :string
+    field :og_image_url, :string
+    field :status, Ecto.Enum, values: [:pending, :processing, :processed, :failed], default: :pending
+    field :error_msg, :string
+
+    timestamps(type: :utc_datetime)
+  end
+
+  @doc false
+  def changeset(open_graph_object, attrs) do
+    open_graph_object
+    |> cast(attrs, [:page_url])
+    |> validate_required([:page_url])
+    |> validate_format(:page_url, ~r/^https?:\/\/\S+$/)
+    |> unique_constraint(:page_url)
+  end
+
+  @doc false
+  def update_changeset(open_graph_object, attrs) do
+    open_graph_object
+    |> cast(attrs, [:og_image_url, :status, :error_msg])
+    |> validate_required([:status])
+  end
+end

lib/og_catalog_web/live/open_graph_object_live/index.ex

@@ -0,0 +1,108 @@
+defmodule OgCatalogWeb.OpenGraphObjectLive.Index do
+  use OgCatalogWeb, :live_view
+
+  alias OgCatalog.OpenGraphObjects
+  alias OgCatalog.OpenGraphObjects.OpenGraphObject
+
+  @impl true
+  def mount(_params, _session, socket) do
+    open_graph_object = %OpenGraphObject{}
+
+    {:ok,
+      socket
+      |> assign(:page_title, "Open graph objects")
+      |> stream(:open_graph_objects, list_open_graph_objects())
+      |> assign(:open_graph_object, open_graph_object)
+      |> assign(:form, to_form(OpenGraphObjects.change_open_graph_object(open_graph_object)))}
+  end
+
+  @impl true
+  def render(assigns) do
+    ~H"""
+    <Layouts.app flash={@flash}>
+      <.header>
+        {@page_title}
+        <:subtitle>Manage open graph object records.</:subtitle>
+      </.header>
+
+      <div class="grid gap-8">
+        <section>
+          <h2 class="text-xl font-bold">Add New Open Graph Object</h2>
+          <.form for={@form} id="open_graph_object-form" phx-change="validate" phx-submit="save">
+            <.input field={@form[:page_url]} type="text" label="Page url" />
+            <footer>
+              <.button phx-disable-with="Saving...">Save Open graph object</.button>
+            </footer>
+          </.form>
+        </section>
+
+        <section>
+          <h2 class="text-xl font-bold">Open Graph Objects</h2>
+          <.table
+            id="open_graph_objects"
+            rows={@streams.open_graph_objects}
+            row_click={fn {_id, open_graph_object} -> JS.navigate(~p"/open_graph_objects/#{open_graph_object}") end}
+          >
+            <:col :let={{_id, open_graph_object}} label="Page url">{open_graph_object.page_url}</:col>
+            <:col :let={{_id, open_graph_object}} label="Status">{open_graph_object.status}</:col>
+            <:col :let={{_id, open_graph_object}} label="Og image url">
+              <img :if={open_graph_object.og_image_url}
+                   src={open_graph_object.og_image_url}
+                   alt={open_graph_object.page_url}
+                   class="max-w-[100px] max-h-[100px] object-cover"/>
+            </:col>
+            <:action :let={{id, open_graph_object}}>
+              <.button
+                phx-click={JS.push("delete", value: %{id: open_graph_object.id}) |> hide("##{id}")}
+                data-confirm="Are you sure?"
+              >
+                Delete
+              </.button>
+            </:action>
+          </.table>
+        </section>
+      </div>
+    </Layouts.app>
+    """
+  end
+
+  @impl true
+  def handle_event("validate", %{"open_graph_object" => params}, socket) do
+    changeset = OpenGraphObjects.change_open_graph_object(socket.assigns.open_graph_object, params)
+    {:noreply, assign(socket, form: to_form(changeset, action: :validate))}
+  end
+
+  @impl true
+  def handle_event("save", %{"open_graph_object" => params}, socket) do
+    case OpenGraphObjects.create_open_graph_object(params) do
+      {:ok, _open_graph_object} ->
+        {:noreply,
+          socket
+          |> put_flash(:info, "Open graph object created successfully")
+          |> stream(:open_graph_objects, list_open_graph_objects(), reset: true)
+          |> assign(:open_graph_object, %OpenGraphObject{})
+          |> assign(:form, to_form(OpenGraphObjects.change_open_graph_object(%OpenGraphObject{})))}
+
+      {:error, %Ecto.Changeset{} = changeset} ->
+        {:noreply, assign(socket, form: to_form(changeset, action: :insert))}
+    end
+  end
+
+  @impl true
+  def handle_event("delete", %{"id" => id}, socket) do
+    open_graph_object = OpenGraphObjects.get_open_graph_object!(id)
+
+    case OpenGraphObjects.delete_open_graph_object(open_graph_object) do
+      {:ok, _deleted} ->
+        {:noreply, stream_delete(socket, :open_graph_objects, open_graph_object)}
+      {:error, _reason} ->
+        {:noreply,
+          socket
+          |> put_flash(:error, "Could not delete open graph object")}
+    end
+  end
+
+  defp list_open_graph_objects() do
+    OpenGraphObjects.list_open_graph_objects()
+  end
+end

lib/og_catalog_web/live/open_graph_object_live/show.ex

@@ -0,0 +1,37 @@
+defmodule OgCatalogWeb.OpenGraphObjectLive.Show do
+  use OgCatalogWeb, :live_view
+
+  alias OgCatalog.OpenGraphObjects
+
+  @impl true
+  def render(assigns) do
+    ~H"""
+    <Layouts.app flash={@flash}>
+      <.header>
+        Open graph object: {@open_graph_object.page_url}
+        <:subtitle>This is an open_graph_object record from your database.</:subtitle>
+        <:actions>
+          <.button navigate={~p"/open_graph_objects"}>
+            <.icon name="hero-arrow-left" />
+          </.button>
+        </:actions>
+      </.header>
+
+      <.list>
+        <:item title="Page url">{@open_graph_object.page_url}</:item>
+        <:item title="Og image url">{@open_graph_object.og_image_url}</:item>
+        <:item title="Status">{@open_graph_object.status}</:item>
+        <:item title="Error msg">{@open_graph_object.error_msg}</:item>
+      </.list>
+    </Layouts.app>
+    """
+  end
+
+  @impl true
+  def mount(%{"id" => id}, _session, socket) do
+    {:ok,
+     socket
+     |> assign(:page_title, "Show Open graph object")
+     |> assign(:open_graph_object, OpenGraphObjects.get_open_graph_object!(id))}
+  end
+end

lib/og_catalog_web/router.ex

@@ -18,6 +18,9 @@ defmodule OgCatalogWeb.Router do
     pipe_through :browser
 
     get "/", PageController, :home
+
+    live "/open_graph_objects", OpenGraphObjectLive.Index, :index
+    live "/open_graph_objects/:id", OpenGraphObjectLive.Show, :show
   end
 
   # Other scopes may use custom stacks.

priv/repo/migrations/20260130201705_create_open_graph_objects.exs

@@ -0,0 +1,18 @@
+defmodule OgCatalog.Repo.Migrations.CreateOpenGraphObjects do
+  use Ecto.Migration
+
+  def change do
+    create table(:open_graph_objects, primary_key: false) do
+      add :id, :binary_id, primary_key: true
+      add :page_url, :string, null: false
+      add :og_image_url, :string
+      add :status, :string, null: false, default: "pending"
+      add :error_msg, :string
+
+      timestamps(type: :utc_datetime)
+    end
+
+    create unique_index(:open_graph_objects, [:page_url])
+    execute("create index open_graph_objects_inserted_at_index on public.open_graph_objects (inserted_at DESC)")
+  end
+end

test/og_catalog/open_graph_objects_test.exs

@@ -0,0 +1,79 @@
+defmodule OgCatalog.OpenGraphObjectsTest do
+  use OgCatalog.DataCase
+
+  alias OgCatalog.OpenGraphObjects
+
+  describe "open_graph_objects" do
+    alias OgCatalog.OpenGraphObjects.OpenGraphObject
+
+    import OgCatalog.OpenGraphObjectsFixtures
+
+    @valid_page_url "https://www.validurl.com/page.html"
+    @nil_attrs %{status: nil, error_msg: nil, og_image_url: nil}
+
+    test "list_open_graph_objects/0 returns all open_graph_objects" do
+      open_graph_object = open_graph_object_fixture()
+      assert OpenGraphObjects.list_open_graph_objects() == [open_graph_object]
+    end
+
+    test "get_open_graph_object!/1 returns the open_graph_object with given id" do
+      open_graph_object = open_graph_object_fixture()
+      assert OpenGraphObjects.get_open_graph_object!(open_graph_object.id) == open_graph_object
+    end
+
+    test "create_open_graph_object/1 with valid data creates an open_graph_object" do
+      valid_attrs = %{page_url: @valid_page_url}
+
+      assert {:ok, %OpenGraphObject{} = open_graph_object} = OpenGraphObjects.create_open_graph_object(valid_attrs)
+      assert open_graph_object.status == :pending
+      assert open_graph_object.error_msg == nil
+      assert open_graph_object.page_url == @valid_page_url
+      assert open_graph_object.og_image_url == nil
+    end
+
+    test "create_open_graph_object/1 with nil data returns error changeset" do
+      all_nil = %{page_url: nil}
+      assert {:error, %Ecto.Changeset{}} = OpenGraphObjects.create_open_graph_object(all_nil)
+    end
+
+    test "create_open_graph_object/1 with invalid page_url returns error changeset" do
+      invalid_page_url = %{page_url: "this_is_an_invalid_url"}
+      assert {:error, %Ecto.Changeset{}} = OpenGraphObjects.create_open_graph_object(invalid_page_url)
+    end
+
+    test "create_open_graph_object/1 with a duplicated page_url returns error changeset" do
+      open_graph_object = open_graph_object_fixture()
+      duplicated_page_url = %{page_url: open_graph_object.page_url}
+      assert {:error, %Ecto.Changeset{}} = OpenGraphObjects.create_open_graph_object(duplicated_page_url)
+    end
+
+    test "update_open_graph_object/2 with valid data updates the open_graph_object" do
+      open_graph_object = open_graph_object_fixture()
+      original_page_url = open_graph_object.page_url
+      update_attrs = %{status: :processing, error_msg: "some updated error_msg", page_url: @valid_page_url, og_image_url: "some updated og_image_url"}
+
+      assert {:ok, %OpenGraphObject{} = open_graph_object} = OpenGraphObjects.update_open_graph_object(open_graph_object, update_attrs)
+      assert open_graph_object.status == :processing
+      assert open_graph_object.error_msg == "some updated error_msg"
+      assert open_graph_object.page_url == original_page_url
+      assert open_graph_object.og_image_url == "some updated og_image_url"
+    end
+
+    test "update_open_graph_object/2 with invalid data returns error changeset" do
+      open_graph_object = open_graph_object_fixture()
+      assert {:error, %Ecto.Changeset{}} = OpenGraphObjects.update_open_graph_object(open_graph_object, @nil_attrs)
+      assert open_graph_object == OpenGraphObjects.get_open_graph_object!(open_graph_object.id)
+    end
+
+    test "delete_open_graph_object/1 deletes the open_graph_object" do
+      open_graph_object = open_graph_object_fixture()
+      assert {:ok, %OpenGraphObject{}} = OpenGraphObjects.delete_open_graph_object(open_graph_object)
+      assert_raise Ecto.NoResultsError, fn -> OpenGraphObjects.get_open_graph_object!(open_graph_object.id) end
+    end
+
+    test "change_open_graph_object/1 returns an open_graph_object changeset" do
+      open_graph_object = open_graph_object_fixture()
+      assert %Ecto.Changeset{} = OpenGraphObjects.change_open_graph_object(open_graph_object)
+    end
+  end
+end