Websockets: how to send a message to all connected clients?

[Martengg]

Hello guys,

I have a problem concerning x/websocket. I tried to figure out a way to send messages to all users when any client sends a message using the websocket example ping.v. I removed the client stuff so there is only a server and one can connect via js or something like this.

Trying to find a solution I thought about adding the client to an array upon connecting. I had a hard time implementing this, and I am still wondering whether there are any easier possibilities.

I am really new to Vlang and wondering how this works. For that reason, I would really appreciate any code examples on how to realize my problem.

Thanks in advance 😄

[medvednikov]

@helto4real can you add an example for this one? Will add it to examples and CI.

[helto4real]

Sure I can, try to find time this weekend @medvednikov

[medvednikov]

Thanks

[helto4real]

@Martengg @medvednikov I have a working example now but I have to PR a small change to make the map of connected clients public from server struct. That I can do tomorrow. I will post a code example that looks similar to the rough prototype here also togehter with the PR:

module main

import time
import os
import x.websocket

fn main() {
	go start_server()
	time.sleep_ms(100)
	go start_client('client 1')
	go start_client('client 2')
	go start_client('client 3')
	println('press enter to quit...')
	os.get_line()
}

fn start_server() ? {
	mut s := websocket.new_server(30000, '')
	// Make that in execution test time give time to execute at least one time
	s.ping_interval = 100
	s.on_connect(fn (mut s websocket.ServerClient) ?bool {
		// Here you can look att the client info and accept or not accept
		// just returning a true/false
		if s.resource_name != '/' {
			return false
		}
		return true
	})?

	s.on_message_ref(fn (mut ws websocket.Client, msg &websocket.Message, mut m websocket.Server) ? {
		for _, cli in m.clients {
			mut c := cli
			if c.client.state == .open && c.client.id !=  ws.id {
				c.client.write_str('broadcast from server: ${msg.payload.str()}') or {
					panic(err)
				}
			}
		}
	}, s)

	s.on_close(fn (mut ws websocket.Client, code int, reason string) ? {
		// println('client ($ws.id) closed connection')
	})
	s.listen() or {
		// println('error on server listen: $err')
	}
	unsafe {
		s.free()
	}
}

fn start_client(name string) ? {
	mut ws := websocket.new_client('ws://localhost:30000')?
	// mut ws := websocket.new_client('wss://echo.websocket.org:443')?
	// use on_open_ref if you want to send any reference object
	ws.on_open(fn (mut ws websocket.Client) ? {
		println('open!')
	})
	// use on_error_ref if you want to send any reference object
	ws.on_error(fn (mut ws websocket.Client, err string) ? {
		println('error: $err')
	})
	// use on_close_ref if you want to send any reference object
	ws.on_close(fn (mut ws websocket.Client, code int, reason string) ? {
		println('closed')
	})
	// use on_message_ref if you want to send any reference object
	ws.on_message(fn (mut ws websocket.Client, msg &websocket.Message) ? {
		if msg.payload.len > 0 {
			message := msg.payload.bytestr()
			println('$ws.id got message:\n$message')
		}
	})

	ws.connect() or {
		println('error on connect: $err')
	}
	// Only first client sends messages that are broadcasted back to all other clients 
	if name == 'client 1' {
		go message_server(mut ws) or {
				println('error on write_echo $err')
		}
	}
	
	ws.listen() or {
		println('error on listen $err')
	}
	unsafe {
		ws.free()
	}
}

fn message_server(mut ws websocket.Client) ? {
	message := 'broadcast this'
	for i := 0; i <= 10; i++ {
		// Server will send pings every 30 seconds
		ws.write_str(message) or {
			println('panicing writing $err')
		}
		time.sleep_ms(1000)
	}
	ws.close(1000, 'normal') or {
		println('panicing $err')
	}
}

[fnetX]

The private client field was exactly our problem. We thought there was most likely a reason for that and tried to look for another way to achieve this ...
Thank you.

[helto4real]

#7922 now fixes this and adds an example

[helto4real]

websocket_server_showcase-2021-01-06_14.17.56.mp4

[fnetX]

@helto4real this is awesome, thank you ...

[helto4real]

Happy to help :)

[Martengg]

Thank you very much!