RxVan/build.gradle at master · yundom/RxVan · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
buildscript {
    ext.kotlin_version = '1.2.50'
    ext.junit_version = '4.12'
    ext.version_name = '1.0.1'

    repositories {
        mavenCentral()
    }
    dependencies {
        classpath "org.jetbrains.kotlin:kotlin-gradle-plugin:$kotlin_version"
    }
}

plugins {
    id "com.jfrog.bintray" version "1.8.1"
}

apply plugin: 'kotlin'
apply plugin: 'maven-publish'

group 'com.yundom'
version version_name

repositories {
    mavenCentral()
}

task sourcesJar(type: Jar, dependsOn: classes) {
    classifier = 'sources'
    from sourceSets.main.allSource
}

task javadocJar(type: Jar, dependsOn: javadoc) {
    classifier = 'javadoc'
    from javadoc.destinationDir
}

artifacts {
    archives sourcesJar, javadocJar
}

publishing {
    publications {
        BintrayPublication(MavenPublication) {
            from components.java
            groupId 'com.yundom'
            artifactId 'rxvan'
            version version_name
            artifact sourcesJar
            artifact javadocJar
        }
    }
}

bintray {
    user = System.getenv("BINTRAY_USER_NAME") ?: ''
    key = System.getenv("BINTRAY_API_KEY") ?: ''
    publications = ['BintrayPublication']
    pkg {
        repo = 'RxVan'
        name = 'RxVan'
        desc = 'A lightweight event bus written in Kotlin'
        licenses = ['MIT']
        vcsUrl = 'https://github.com/yundom/rxvan'
        version {
            name = "v$version_name"
            released = new Date()
            vcsTag = version_name
        }
    }
}

dependencies {
    compile "org.jetbrains.kotlin:kotlin-stdlib-jdk8:$kotlin_version"
    compile "io.reactivex.rxjava2:rxjava:2.1.14"

    testCompile "junit:junit:$junit_version"
}