Can't get a CfnInstance with instance.getInstance()

[johnjelinek]

🐛 Bug Report

What is the problem?

Can't get a CfnInstance with instance.getInstance(). I was hoping to get a CfnInstance to see if I can pass it in to Targets of CfnMaintenanceWindowTargetProps.

Reproduction Steps

(let [app (new App)
      stack (new Stack app "stack" stack-props)
      vpc (new Vpc stack "vpc")
      instance (new Instance stack "server" instance-props)
      window (new CfnMaintenanceWindow stack "window" maintenance-window-props)
      target (new CfnMaintenanceWindowTarget stack "target" maintenance-window-target-props)]
  (.getInstance instance)
  (.synth app))

Verbose Log

Execution error (IllegalArgumentException) at com.fasterxml.jackson.databind.introspect.POJOPropertyBuilder/getSetter (POJOPropertyBuilder.java:497).
Conflicting setter definitions for property "networkInterfaces": software.amazon.awscdk.services.ec2.CfnInstance#setNetworkInterfaces(1 params) vs software.amazon.awscdk.services.ec2.CfnInstance#setNetworkInterfaces(1 params)
class software.amazon.jsii.JsiiException

or

Execution error (IllegalArgumentException) at com.fasterxml.jackson.databind.introspect.POJOPropertyBuilder/getSetter (POJOPropertyBuilder.java:497).
Conflicting setter definitions for property "blockDeviceMappings": software.amazon.awscdk.services.ec2.CfnInstance#setBlockDeviceMappings(1 params) vs software.amazon.awscdk.services.ec2.CfnInstance#setBlockDeviceMappings(1 params)

Environment

• CDK CLI Version: 1.8.0 (build 5244f97)
• Module Version: 1.8.0.DEVPREVIEW
• OS: MacOS Mojave
• Language: Java

Other information

JsiiObjectMapper.java:	57	software.amazon.jsii.JsiiObjectMapper/treeToValue
JsiiObject.java:	111	software.amazon.jsii.JsiiObject/jsiiGet
Instance.java:	66	software.amazon.awscdk.services.ec2.Instance/getInstance
RestFn.java:	1523	clojure.lang.RestFn/invoke
AFn.java:	22	clojure.lang.AFn/run
AFn.java:	22	clojure.lang.AFn/run
Thread.java:	748	java.lang.Thread/run

[johnjelinek]

If I pass the instance in a list directly to .targets, I get this stack trace:

Resolution error: Resolution error: Trying to resolve() a Construct at /Resources/${Token[maintenance-window-target.LogicalID.82]}/Properties/targets/0/node.

[johnjelinek]

hmm ... I'm starting to think maybe Instance isn't all that baked and that I need to be building a CfnInstance at this point.

[jeshan]

you need to show us what your instance-props, maintenance-window-props and maintenance-window-target-props look like

[johnjelinek]

@jeshan: here's the whole kit n' caboodle:

(ns cdk.app
  (:import (software.amazon.awscdk.core App
                                        CfnOutput
                                        CfnOutputProps
                                        Environment
                                        Stack
                                        StackProps)
           (software.amazon.awscdk.services.ec2 GenericWindowsImage
                                                Instance
                                                InstanceClass
                                                InstanceProps
                                                InstanceSize
                                                InstanceType
                                                Port
                                                SubnetConfiguration
                                                SubnetSelection
                                                SubnetType
                                                Vpc
                                                VpcProps
                                                WindowsImage
                                                WindowsVersion)
           (software.amazon.awscdk.services.iam ManagedPolicy
                                                ServicePrincipal
                                                Role
                                                RoleProps)
           (software.amazon.awscdk.services.ssm CfnMaintenanceWindow
                                                CfnMaintenanceWindowProps
                                                CfnMaintenanceWindowTarget
                                                CfnMaintenanceWindowTargetProps)))

(def keypair-name "my-keypair")
(def default-cidr "172.16.0.0/16")
(def windows-instance-type
  (InstanceType/of InstanceClass/BURSTABLE3 InstanceSize/LARGE))
(def windows-rdp-port (Port/tcp 3389))

(def latest-windows-ami
  (new WindowsImage WindowsVersion/WINDOWS_SERVER_2019_ENGLISH_FULL_BASE))

(def pinned-windows-ami
  (new GenericWindowsImage {"us-east-2" "ami-017894519635aafd2"}))

(def public-subnet-selection
  (-> (SubnetSelection/builder)
      (.subnetType SubnetType/PUBLIC)
      .build))

(defn instance-props [vpc role]
  (-> (InstanceProps/builder)
      (.instanceType windows-instance-type)
      (.keyName keypair-name)
      (.machineImage pinned-windows-ami)
      (.role role)
      (.vpc vpc)
      (.vpcSubnets public-subnet-selection)
      .build))

(def instance-role-props
  (-> (RoleProps/builder)
      (.assumedBy (new ServicePrincipal "ec2.amazonaws.com"))
      (.managedPolicies [(ManagedPolicy/fromAwsManagedPolicyName
                          "service-role/AmazonEC2RoleforSSM")
                         (ManagedPolicy/fromAwsManagedPolicyName
                          "AmazonSSMFullAccess")])
      .build))

(def stack-props
  (-> (StackProps/builder)
      (.env (-> (Environment/builder)
                (.region "us-east-2")
                .build))
      .build))

(def subnet-configuration
  (-> (SubnetConfiguration/builder)
      (.name "Public")
      (.subnetType SubnetType/PUBLIC)
      .build))

(def vpc-props
  (-> (VpcProps/builder)
      (.cidr default-cidr)
      (.subnetConfiguration [subnet-configuration])
      .build))

(def maintenance-window-props
  (-> (CfnMaintenanceWindowProps/builder)
      (.allowUnassociatedTargets false)
      (.cutoff 2)
      (.schedule "cron(* 17 * * ? *)")
      (.description
       "Maintenance window to allow for patching windows instances")
      (.duration 6)
      (.name "example-windows-maintenance-window")
      .build))

(defn maintenance-window-target-props [instance maintenance-window]
  (-> (CfnMaintenanceWindowTargetProps/builder)
      (.ownerInformation "Example")
      (.description "Maintenance Window for Example instance")
      (.resourceType "INSTANCE")
      (.targets [{"key" "InstanceIds" "values" []}])
      (.name "example-patch-targets")
      (.windowId (.getRef maintenance-window))
      .build))

;; entry-point

(defn -main []
  (let [app (new App)
        stack (new Stack app "example" stack-props)
        vpc (new Vpc stack "example-vpc" vpc-props)
        instance-patching-role (new Role stack "patching-role"
                                    instance-role-props)
        maintenance-window (new CfnMaintenanceWindow stack "maintenance-window"
                                maintenance-window-props)
        instance (new Instance stack "server" (instance-props
                                               vpc
                                               instance-patching-role))
        maintenance-window-target (new CfnMaintenanceWindowTarget maintenance-window "maintenance-window-target"
                                       (maintenance-window-target-props instance maintenance-window))]
    (doto (.getConnections instance)
      (.allowFromAnyIpv4 windows-rdp-port "RDP"))
    (.synth app)))

[johnjelinek]

note: I was trying to shove instance in another way with (.targets [{"key" "InstanceIds" "values" [instance]}]) -- but I think that would also mean I need to (.getInstance instance), which results in the error referenced above

[johnjelinek]

it looks like I am able to finagle my way to success with this:

(.targets [{"key" "tag:Name" "values" [(.getPath (.getNode instance))]}])

[johnjelinek]

ideally this would just work: (.targets [instance])

[johnjelinek]

This also resolves: (.targets [{"key" "InstanceIds" "values" [(.getInstanceId instance)]}])