Question: new fzf feature reload inside vim

[monkoose]

• Category
  • Question
  • Bug
  • Suggestion

Is it possible to use it and execute vim function or command? If yes, can you please explain how to do it. Because my several attempts failed with [Command failed: ...].
Or by now only possible way is to imitate same command as source of fzf#run?
Thank you.

[junegunn]

Because my several attempts failed

Please post the code you tried.

[junegunn]

function! RipgrepFzf(query, fullscreen)
  let command_fmt = 'rg --column --line-number --no-heading --color=always --smart-case %s || true'
  let initial_command = printf(command_fmt, shellescape(a:query))
  let reload_command = printf(command_fmt, '{q}')
  let options = {'options': ['--phony', '--query', a:query, '--bind', 'change:reload:'.reload_command]}
  call fzf#vim#grep(initial_command, 1, options, a:fullscreen)
endfunction

command! -nargs=1 -bang RF call RipgrepFzf(<q-args>, <bang>0)

This works for me. There is one problem though, that the command requires an initial query. This is to avoid starting ripgrep command for an empty query that can run for a very long time producing a lot of lines. And fzf cannot kill the initial command on "change", because it wasn't started by fzf process.

# fzf can kill subsequent-rg-command because it started it, but not initial-rg-command
initial-rg-command | fzf ... --bind 'change:reload:subsequent-rg-command'

A workaround is to set FZF_DEFAULT_COMMAND and start fzf without the standard input command.

# fzf can now kill both initial command and subsequent command
FZF_DEFAULT_COMMAND=initial-rg-command \
  fzf ... --bind 'change:reload:subsequent-rg-command'

However, fzf#vim#grep currently doesn't have an option for this mode of execution, but I can change that.

[junegunn]

Now this works well with the above commit.

function! RipgrepFzf(query, fullscreen)
  let command_fmt = 'rg --column --line-number --no-heading --color=always --smart-case %s || true'
  let initial_command = printf(command_fmt, shellescape(a:query))
  let reload_command = printf(command_fmt, '{q}')
  let options = {'options': ['--phony', '--query', a:query, '--bind', 'change:reload:'.reload_command]}
  call fzf#vim#grep(initial_command, 1, fzf#vim#with_preview(options), a:fullscreen)
endfunction

command! -nargs=* -bang RF call RipgrepFzf(<q-args>, <bang>0)

[monkoose]

Thank you.

[amebrahimi]

I have an issue about this topic when I try to start :Rg I get this error:

and here is my fzf vim settings file:

nnoremap <C-p> :GFiles<CR>
map <C-f> :Files<CR>
map <leader>b :Buffers<CR>
nnoremap <leader>g :Rg<CR>
nnoremap <leader>m :Marks<CR>

let g:fzf_layout = {'up':'~90%', 'window': { 'width': 0.8, 'height': 0.8,'yoffset':0.5,'xoffset': 0.5, 'highlight': 'Todo', 'border': 'sharp'  } }
let $FZF_DEFAULT_OPTS = '--layout=reverse --info=inline'
let $FZF_DEFAULT_COMMAND = 'rg --files --hidden'

let g:fzf_action = {
  \ 'ctrl-t': 'tab split',
  \ 'ctrl-x': 'split',
  \ 'ctrl-v': 'vsplit' }


let g:fzf_colors =
  \ { 'fg':      ['fg', 'Normal'],
  \ 'bg':      ['bg', 'Normal'],
  \ 'hl':      ['fg', 'Comment'],
  \ 'fg+':     ['fg', 'CursorLine', 'CursorColumn', 'Normal'],
  \ 'bg+':     ['bg', 'CursorLine', 'CursorColumn'],
  \ 'hl+':     ['fg', 'Statement'],
  \ 'info':    ['fg', 'PreProc'],
  \ 'border':  ['fg', 'Ignore'],
  \ 'prompt':  ['fg', 'Conditional'],
  \ 'pointer': ['fg', 'Exception'],
  \ 'marker':  ['fg', 'Keyword'],
  \ 'spinner': ['fg', 'Label'],
  \ 'header':  ['fg', 'Comment'] }

let g:fzf_tags_command='ctags -R'

"Get Files
command! -bang -nargs=? -complete=dir Files
            \ call fzf#vim#files(<q-args>, fzf#vim#with_preview({'options': ['--layout=reverse', '--info=inline']}), <bang>0)

" Get text in files with Rg
command! -bang -nargs=* Rg
    \ call fzf#vim#grep(
    \   'rg --column --line-number --no-heading --color=always --smart-case'.shellescape(<q-args>), 1,
    \   fzf#vim#with_preview(), <bang>0)

function! RipgrepFzf(query, fullscreen)
    let command_fmt = 'rg --column --line-number --no-heading --color=always --smart-case %s || true'
    let initial_command = printf(command_fmt, shellescape(a:query))
    let reload_command = printf(command_fmt, '{q}')
    let options = {'options': ['--phony', '--query', a:query, '--bind', 'change:reload:'.reload_command]}
    call fzf#vim#grep(initial_command, 1, fzf#vim#with_preview(options), a:fullscreen)
endfunction

command! -nargs=* -bang RF call RipgrepFzf(<q-args>, <bang>0)

command! -bang -nargs=* GGrep
            \ call fzf#vim#grep(
            \ 'git grep --line-number '.shellescape(<q-args>), 0,
            \ fzf#vim#with_preview({'dir': systemlist('git rev-parse --show-toplevel')[0]}), <bang>0)

[upgradeQ]

@amebrahimi I had the same issue , turns out I've not installed rg , maybe it is the case?
Since you on windows try running this command : choco install ripgrep