Consider making it easier to use without flakes and overlays

[CobaltCause]

Assuming rust-overlay is bound to a path to the rust-overlay source, and nixpkgs is bound to an imported nixpkgs instance, currently you have to do this:

nixpkgs.lib.fixedPoints.fix (rust-bin:
  import "${rust-overlay}/lib/rust-bin.nix" {
    inherit (nixpkgs) lib pkgs;
    inherit (rust-bin) nightly;
    manifests = import "${rust-overlay}/lib/manifests.nix" {
      inherit (nixpkgs) lib;
      distRoot = import "${rust-overlay}/lib/dist-root.nix";
    };
  }
)

which is a mouthful, and I suspect these file paths and such are not considered public API. It would be nice to be able to use this more easily without flakes and overlays.

[oxalica]

If you accept manually fixing the overlay (but without re-instantiating nixpkgs), it is simpler to use public overlay entry point default.nix:

{ lib, pkgs, rust-overlay }:
let 
  rust-bin = (lib.fix (final: pkgs // (import rust-overlay) final pkgs)).rust-bin;
in
  /*..*/

We can also extract lib.mkRustBin from flake into another public entry point file, eg a root /rust-bin.nix. It should be easy since it does not relying on any flake mechanics. PR is welcome.

[milahu]

related stackoverflow question
How can I use a specific build of Rust in a nixpkgs derivation?

[milahu]

the "no overlay" version breaks
as soon as a project has non-rust dependencies like openssl

$ ldd $(which rqbit) | grep "not found"
        libssl.so.3 => not found
        libcrypto.so.3 => not found

so a "no flakes" version could look like this

{
  fetchFromGitHub,
}:

let
  # https://github.com/oxalica/rust-overlay/issues/209
  rust-overlay-src = fetchFromGitHub {
    owner = "oxalica";
    repo = "rust-overlay";
    rev = "971d18658c83f3a6a434ac647798141fddce3175";
    hash = "sha256-LTgfljA/X8aGEXk/EUVoLL+0wfJjQAhF/rUQOFsx+/U=";
  };
  # re-evaluate pkgs
  pkgsWithOverlay = import <nixpkgs> {
    overlays = [ (import rust-overlay-src) ];
  };
in

with pkgsWithOverlay;

let
  rustSpecific = rust-bin.stable.latest.default;
  # rustSpecific = (rustChannelOf { channel = "1.90.0"; }).rust;
  rustPlatform = makeRustPlatform {
    cargo = rustSpecific;
    rustc = rustSpecific;
  };
in  

rustPlatform.buildRustPackage {
  # ...
}

but this breaks as soon as you need packages outside of <nixpkgs>
so for example in a nur-packages repo
you would have to apply the rust-overlay as soon as possible